home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 12: Textmags & Docs / nf_archive_12.iso / MAGS / SOURCES / ATARI_SRC.ZIP / atari source / AHDI / TTDRIVER / ACSC / ACSC.S < prev    next >
Encoding:
Text File  |  2001-02-09  |  53.9 KB  |  2,362 lines
  1. * acsc.s
  2.     .include "version.s"
  3.  
  4. sermsg        equ    0        ; for timeout messages
  5. sahdxc        equ    0        ; simple atari hard disk command
  6. format        equ    0        ; include Format code
  7. mdsense        equ    0        ; include Mode Sense code
  8. ospool        equ    0        ; increase size of OS pool for ROM
  9. SCSI        equ    1        ; include SCSI code
  10. MC68030        equ    1        ; running on a '30
  11. VERBOSE        equ    0        ; messages out ST MFP port task time
  12. * SCDMA        equ    1        ; use DMA for SCSI transfers
  13.  
  14.   .if MC68030
  15.     .include "68030.s"
  16.   .endif ;MC68030
  17.  
  18. * default drive size (one and only one of the following)
  19. s10mb        equ    0
  20. s20mb        equ    0
  21. s11mb        equ    1
  22.  
  23. *------------------------------------------------------------------------
  24. *                                    :
  25. *    ST SASI/AHDI hard disk driver                    :
  26. *    Copyright 1985 Atari Corp.                    :
  27. *                                    :
  28. *----                                    :
  29.  
  30. * $Log:    ahdi.s,v $
  31. * Revision 1.6  86/06/13  10:56:37  dyer
  32. * Install boot-load handler code, fix some bugs and minor
  33. * misfeatures in the hard disk access code.
  34. * 
  35. * Revision 1.5  86/04/24  17:18:23  dyer
  36. * Add logs, fix typos, remove garbage.
  37. * 
  38.  
  39. *----
  40. *  9-Apr-1985 lmd    Hacked it up.  "Gee, it seems to work ..."    :
  41. * 14-Apr-1985 lmd    linked with BIOS (***FOR NOW***)        :
  42. * 20-Apr-1985 lmd    hacked for WD controller (now, wired...)    :
  43. * 24-Jun-1985 jwt    hacked for Adaptec, new kludge board        :
  44. * 01-Jul-1985 jwt    seems to work, add more formatting and more    :
  45. *             detailed error reporting            :
  46. * 22-Jul-1985 jwt    change timing of wdc/wdl at start of command,    :
  47. *             added extra move.w $8a,wdl to change A1    :
  48. * 23-Jul-1985 jwt    use a move.l instruction for all wdc/wdl write    :
  49. *             pairs since it changes A1 quickly enough that    :
  50. *             the (old) DMA chip does not incorrectly    :
  51. *             generate two chip selects            :
  52. * 26-Sep-1985 jwt v0.05    support multiple ACSI devices            :
  53. *            separate timeouts for command packet and    :
  54. *             operation                    :
  55. * 01-Oct-1985 jwt v0.06    added some AUXout serial debug messages        :
  56. *            was responding to one more drive than was there    :
  57. * 07-Oct-1985 jwt v0.07    added support for multiple partitions/drive    :
  58. * 11-Oct-1985 jwt v0.08 added delay loop after pread for completion    :
  59. *             byte                        :
  60. * 19-Oct-1985 jwt v0.09    remove format and simple commands from resident :
  61. *             part                        :
  62. *            conditional assembly for default size        :
  63. *            added count parameter to pread            :
  64. * 22-Oct-1985 jwt v0.10    make certain qdone returns d0=-1 on timeout    :
  65. *            add bits to read/write flag for:        :
  66. *             retry disable (bit 2)                :
  67. *             physical unit operation (bit 3)        :
  68. *            add pun_ptr to TOS global variables        :
  69. * 24-Oct-1985 jwt v0.11    add critical error call on errors        :
  70. * 30-Jan-1986 lmd v0.12    increase OS pool by 128 chunks for ROM release    :
  71. *             of 11/20/85                    :
  72. *          jwt    stay resident if any physical units found    :
  73. *             rather than if any GEM partitions found    :
  74. * 05-Feb-1986 jwt    call critical error handler on errors unless    :
  75. *             no-retry bit is set                :
  76. *            conditional assembly format code        :
  77. *            remove transfer only to even byte boundary    :
  78. *             restriction                    :
  79. *            remove transfer less than 128K restriction    :
  80. *            check for 0 length transfer            :
  81. * 06-Feb-1986 jwt v0.13    use register based accesses for wdc and wdl    :
  82. * 25-Mar-1986 lmd v0.14 Enforce .0005 (200th) sec delay between        :
  83. *            successive calls to _do_rw().  SCSI adapter    :
  84. *            board eats the controller's completion byte,    :
  85. *            so we have to delay for it.            :
  86. * 24-Apr-1986 lmd v1.1    Hack pool_install code to increase pool for    :
  87. *            other ROM releases of the system.        :
  88. * 24-Apr-1986 lmd v1.4    Print nasty messages for old disk-based and    :
  89. *            unauthorized ROM-based systems.            :
  90. * 23-Jun-1987 lmd v1.5  Fix date-check in nasty-OS-message code; wrong    :
  91. *            offset into the OS header (now $1e).        :
  92. *                                    :
  93. * 06-Nov-1987 akp v1.7    Added procedure findpackages and call to it.    :
  94. * 10-Nov-1987 akp    Changed source to MADMAC format.        :
  95. *            Removed format flag from top of file.        :
  96. * 24-Nov-1987 akp    Really made v1.7 work.                :
  97. * 19-Feb-1987 ml    Added format and mode sense code for use in     :
  98. *            HDX  (It's conditional, code will only be    :
  99. *            included for ahdi.prg, and not shdriver.sys).    :
  100. * 23-Feb-1989 jwt    hack in some SCSI 5380 code
  101. *------------------------------------------------------------------------
  102.  
  103. etv_critic    equ    $404        ; critical error handoff vector
  104. phystop        equ    $42e        ; physical top of memory
  105. flock        equ    $43e        ; FIFO lock variable
  106. _bootdev    equ    $446        ; default boot device
  107. _hz_200        equ    $4ba        ; system 200hz timer
  108. hdv_init    equ    $46a        ; hdv_init()
  109. hdv_bpb        equ    $472        ; hdv_bpb(dev)
  110. hdv_rw        equ    $476        ; hdv_rw(rw, buf, count, recno, dev)
  111. hdv_boot    equ    $47a        ; hdv_boot()
  112. hdv_mediach    equ    $47e        ; hdv_mediach(dev)
  113. _drvbits    equ    $4c2        ; block device bitVector
  114. _dskbufp    equ    $4c6        ; pointer to common disk buffer
  115. pun_ptr        equ    $516        ; pointer to physical unit table
  116.  
  117. maxunits    equ    16        ; maximum number of units
  118. nretries    equ    3        ; #retries-1
  119.  
  120. MAXSECTORS    equ    254        ; maximum number of sectors at one gulp
  121.  
  122. EWRITF        equ    -10        ; GEMDOS error codes
  123. EREADF        equ    -11
  124. CRITRETRY    equ    $00010000    ; "retry" return code
  125.  
  126.  .if ospool
  127. _sysbase    = $4f2            ; -> base of OS
  128. numchunks    = 128            ; #chunks to add to pool
  129. chunksiz    = 66            ; #bytes/chunk
  130. chunkno        = 4            ; chunk# (4 16-byte chunks)
  131.  .endif
  132.  
  133. * ---------------- Installer ----------------
  134.     .globl    i_sasi
  135. i_sasi:    bra.w    i_sasi1            ; GEMDOS entry-point
  136.     st    bootloaded        ; boot entry-point, set flag
  137.     move.l    a2,baseaddr        ; install base address
  138.     bra    i_sasi1            ; (continue with normal initialization)
  139.  
  140. bootloaded:    dc.w    0        ; nonzero if loaded from boot sector
  141. baseaddr:    dc.l    0        ; -> base addr of .PRG file
  142.  
  143.     dc.b    '@(#)acsc.s '
  144.   .if !SCDMA
  145.     dc.b    '(ND) '
  146.   .endif ;SCDMA
  147.     dc.b    ' '
  148.     VERSION
  149.     dc.b    $0d,$0a,0,$1A
  150.     .even
  151.  
  152. * page 
  153. * ---------------- Front End ----------------
  154.  
  155.  
  156. *+
  157. * LONG hbpb(dev) - return ptr to BPB (or NULL)
  158. *
  159. * Passed:    dev    4(sp).W
  160. *
  161. *-
  162. hbpb:
  163.     move.w    4(sp),d0        ; d0 = devno
  164.     clr    d1            ; d1 = 0, physical op not possible
  165.     move.l    o_bpb,a0        ; a0 -> pass-through vector
  166.     lea    _sasi_bpb(pc),a1    ; a1 -> our handler
  167.     bra    check_dev        ; do it
  168.  
  169.  
  170.  
  171. *+
  172. * LONG hrw(rw, buf, count, recno, dev)
  173. *
  174. * Passed:    dev    $e(sp).W
  175. *        recno    $c(sp).W
  176. *        count    $a(sp).W
  177. *        buf    6(sp).L
  178. *        rw    4(sp).W
  179. *
  180. *-
  181. hrw:
  182.     move.w    $e(sp),d0        ; d0 = devno
  183.     move.w    4(sp),d1        ; d1 includes physical device flag
  184.     move.l    o_rw,a0            ; a0 -> pass-through vector
  185.     lea    _sasi_rw(pc),a1        ; a1 -> our handler
  186.     bra    check_dev        ; do it
  187.  
  188.  
  189.  
  190. *+
  191. * LONG hmediach(dev)
  192. *
  193. * Passed:    dev    4(sp).W
  194. *
  195. *-
  196. hmediach:
  197.     move.w    4(sp),d0        ; d0 = devno
  198.     clr    d1            ; physical operation not possible
  199.     move.l    o_mediach,a0        ; a0 -> pass-through vector
  200.     lea    _sasi_mediach(pc),a1    ; a1 -> our handler
  201.  
  202.  
  203. *+
  204. * check_dev - use handler, or pass vector through
  205. *
  206. * Passed:    d0.w = device#
  207. *        d1, bit 3  1=physical operation
  208. *        a0 ->  old handler
  209. *        a1 ->  new handler
  210. *        a5 ->  $0000 (zero-page ptr)
  211. *
  212. * Jumps-to:    (a1) if dev in range for this handler
  213. *        (a0) otherwise
  214. *
  215. *-
  216. check_dev:
  217.     btst    #3,d1            ; is this a physical unit operation?
  218.     beq    chkd_a
  219.  
  220. ;    subq    #2,d0            ; lowest device is C
  221. ;    bmi    chkd_f            ; not one of ours
  222.  
  223. ;    cmp    puns,d0
  224. ;    bge    chkd_f
  225.     bra    chkd_s
  226.  
  227. chkd_a:    lea    pun,a2            ; pointer to pun map
  228.     tst.b    0(a2,d0.w)        ; must be positive for a real unit
  229.     bmi    chkd_f
  230. chkd_s:    move.l    a1,a0            ; yes -- follow success vector
  231. chkd_f:    jmp    (a0)            ; do it
  232.  
  233.  
  234.  
  235. * page 
  236. * ---------------- Medium level driver ----------------
  237.  
  238. *+
  239. * _sasi_init - initialize SASI dev
  240. * Passed:    nothing
  241. * Returns:    d0 < 0: error
  242. *        d0 ==0: success
  243. *-
  244.     .globl    _sasi_init
  245. _sasi_init:
  246.     clr.l    d0
  247.     rts
  248.  
  249. *+
  250. * _sasi_bpb - return BPB for hard drive
  251. * Synopsis:    LONG _sasi_bpb(dev)
  252. *        WORD dev;
  253. *
  254. * Returns:    NULL, or a pointer to the BPB buffer
  255. *
  256. *-
  257.     .globl    _sasi_bpb
  258. _sasi_bpb:
  259.     move.w    4(sp),d0        ; get device number
  260.     mulu.w    #BPBLEN,d0
  261.     add.l    #bpbs,d0
  262.     rts
  263.  
  264. * page 
  265. *+
  266. * _ahdi_rw - read/write hard sectors
  267. *     aka _sasi_rw for historical reasons
  268. *
  269. * Synopsis:    _ahdi_rw(rw, buf, count, recno, dev)
  270. *
  271. * Passed:    dev    $e(sp).W
  272. *        recno    $c(sp).W
  273. *        count    $a(sp).W
  274. *        buf    6(sp).L
  275. *        rw    4(sp).W        ; non-zero -> write
  276. *
  277. *-
  278.  
  279. * stack frame offsets
  280. xrw    equ    8
  281. xbuf    equ    10
  282. xcount    equ    14
  283. xrecno    equ    16
  284. xdev    equ    18
  285. xlrecno    equ    20
  286.  
  287.     .globl    _sasi_rw
  288.     .globl    _ahdi_rw
  289. _sasi_rw:
  290. _ahdi_rw:
  291.     link    a6,#0            ; create a frame pointer
  292.  
  293. ahrw1:    move.w    xcount(a6),d2        ; is there anything to be done?
  294.     beq    ahrw6            ; no, so done with no errors
  295.  
  296.   .if SCSI
  297.     move.w    xdev(a6),d1        ; get the device number
  298.     move.w    xrw(a6),d3        ; see if this is to be a phys op
  299.     btst    #3,d3
  300.     beq.s    .1            ; no, logical operation
  301.     cmpi.w    #9,d1            ; is it bigger than largest ACSI unit?
  302.     ble.s    ahrw11            ; no, so must be phys ACSI
  303.     bra    scrw
  304.  
  305. .1:    lea    pun,a2
  306.     move.b    0(a2,d1.w),d0        ; get logical unit flags
  307.     btst    #6,d0            ; is the SCSI bit set?
  308.     bne    scrw            ; yes, so a SCSI operation
  309.   .endif ;SCSI
  310.     
  311. ahrw11:    move.l    xbuf(a6),d1        ; if all goes well, this is our buffer
  312.  
  313.     cmpi.w    #MAXSECTORS,d2        ; more than one DMAfull?
  314.     ble    ahrw2
  315.     move.w    #MAXSECTORS,d2        ; yes, so only do this many this time
  316.  
  317. ahrw2:    btst    #0,xbuf+3(a6)        ; an odd boundary?
  318.     beq    ahrw4            ; no, so do normally
  319.  
  320.     cmpi.w    #2,d2            ; can only do 2 at a time tops this way
  321.     ble    ahrw3
  322.     move.w    #2,d2
  323.  
  324. ahrw3:    move.l    _dskbufp,d1        ; use the bios buffer for this transfer
  325.  
  326.     btst    #0,xrw+1(a6)        ; is this a write?
  327.     beq    ahrw4            ; no, so go fill buffer from disk
  328.  
  329.     movea.l    d1,a1            ; dest
  330.     movea.l    xbuf(a6),a2        ; source
  331.     bsr    smove            ; move d2 sectors from a2 to a1
  332.  
  333. ahrw4:    move.w    d2,-(sp)        ; preserve count this time
  334.  
  335.     move.w    xdev(a6),-(sp)
  336.     move.w    xrecno(a6),-(sp)
  337.     move.w    d2,-(sp)        ; count
  338.     move.l    d1,-(sp)        ; buffer
  339.     move.w    xrw(a6),-(sp)
  340.     bsr    _do_rw
  341.     adda.w    #12,sp
  342.  
  343.     move.w    (sp)+,d2        ; restore count for this op
  344.  
  345.     tst.l    d0            ; any errors there?
  346.     bne    ahrw7            ; yes, so give up
  347.  
  348.     btst    #0,xbuf+3(a6)        ; if odd boundary
  349.     beq    ahrw5
  350.     btst    #0,xrw+1(a6)        ; and a read
  351.     bne    ahrw5
  352.  
  353.     movea.l    xbuf(a6),a1        ; we must move dskbuf to desired dest
  354.     movea.l    _dskbufp,a2
  355.     bsr    smove
  356.  
  357. ahrw5:    move.w    d2,d0            ; number we did
  358.     ext.l    d0
  359.     asl.l    #8,d0            ; *512
  360.     asl.l    #1,d0
  361.     add.l    d0,xbuf(a6)        ; buf += (sectors_done * sector size)
  362.     add.w    d2,xrecno(a6)
  363.     sub.w    d2,xcount(a6)
  364.     bne    ahrw1
  365.  
  366. ahrw6:    clr.l    d0        ; got here with no errors!
  367. ahrw7:
  368.   .if MC68030
  369.     move.l    d0,-(sp)    ; save the status
  370.     move    sr,-(sp)
  371.     ori    #$700,sr    ; no interrupts right now please
  372.  
  373.     movecacrd0
  374.  
  375.     btst    #7,xrw(a6)    ; are we supposed to leave I cache alone?
  376.     bne.s    .91        ; yes
  377.  
  378.     ori    #$8,d0        ; dump the I cache
  379.  
  380. .91:    btst    #6,xrw(a6)    ; are we supposed to leave D cache alone?
  381.     bne.s    .92        ; yes
  382.  
  383.     ori    #$800,d0    ; dump the D cache
  384.  
  385. .92:    moved0cacr
  386.     move    (sp)+,sr    ; restore interrupt state
  387.  
  388.     move.l    (sp)+,d0    ; restore the return value
  389.   .endif ;MC68030
  390.     unlk    a6
  391.     rts
  392.  
  393. *+
  394. * smove -- move d2.w sectors from a2 to a1
  395. *    d2 is known to be either 1 or 2
  396. *-
  397.  
  398. smove:    move.w    d2,d0
  399.     asl.w    #8,d0
  400.     asl.w    #1,d0
  401.     subq.w    #1,d0            ; dbra likes one less
  402. smove1:    move.b    (a2)+,(a1)+
  403.     dbra    d0,smove1
  404.     rts
  405.  
  406. * page 
  407. *+
  408. * scrw -- a SCSI disk rwabs()
  409. *-
  410.   .if SCSI
  411. REGBASE    equ    1    ; most are on odd part of data bus
  412. REGSTEP    equ    2    ; most registers are on word boundaries
  413.  
  414. ; 68901 MFP definitions
  415.  
  416. MFP    equ    $FFFFFA01
  417.  
  418. ;GPIP    equ    MFP+$00
  419. AER    equ    MFP+$02
  420. DDR    equ    MFP+$04
  421. IERA    equ    MFP+$06
  422. IERB    equ    MFP+$08
  423. IPRA    equ    MFP+$0A
  424. IPRB    equ    MFP+$0C
  425. ISRA    equ    MFP+$0E
  426. ISRB    equ    MFP+$10
  427. IMRA    equ    MFP+$12
  428. IMRB    equ    MFP+$14
  429. VR    equ    MFP+$16
  430. TACR    equ    MFP+$18
  431. TBCR    equ    MFP+$1A
  432. TCDCR    equ    MFP+$1C
  433. TADR    equ    MFP+$1E
  434. TBDR    equ    MFP+$20
  435. TCDR    equ    MFP+$22
  436. TDDR    equ    MFP+$24
  437. SCR    equ    MFP+$26
  438. UCR    equ    MFP+$28
  439. RSR    equ    MFP+$2A
  440. TSR    equ    MFP+$2C
  441. UDR    equ    MFP+$2E
  442.  
  443. MFP2    equ    $FFFFFA81
  444. GPIP2    equ    MFP2+$00
  445. AER2    equ    MFP2+$02
  446. DDR2    equ    MFP2+$04
  447. IERA2    equ    MFP2+$06
  448. IERB2    equ    MFP2+$08
  449. IPRA2    equ    MFP2+$0A
  450. IPRB2    equ    MFP2+$0C
  451. ISRA2    equ    MFP2+$0E
  452. ISRB2    equ    MFP2+$10
  453. IMRA2    equ    MFP2+$12
  454. IMRB2    equ    MFP2+$14
  455. VR2    equ    MFP2+$16
  456. TACR2    equ    MFP2+$18
  457. TBCR2    equ    MFP2+$1A
  458. TCDCR2    equ    MFP2+$1C
  459. TADR2    equ    MFP2+$1E
  460. TBDR2    equ    MFP2+$20
  461. TCDR2    equ    MFP2+$22
  462. TDDR2    equ    MFP2+$24
  463. SCR2    equ    MFP2+$26
  464. UCR2    equ    MFP2+$28
  465. RSR2    equ    MFP2+$2A
  466. TSR2    equ    MFP2+$2C
  467. UDR2    equ    MFP2+$2E
  468.     
  469. ; GPIP2 BIT ASSIGNMENTS
  470. GPIP2SCSI    equ    7    ; SCSI xIRQ
  471. GPIP2RTC    equ    6    ; RTC IRQ
  472. GPIP25        equ    5    ; 
  473. GPIP2CHGL    equ    4    ; ChangeLine
  474. GPIP2RI        equ    3    ; Ring Indicator (SCC Port B)
  475. GPIP2DBE    equ    2    ; DMA Bus Error
  476. LED1        equ    1    ; debug LED
  477. LED0        equ    0    ; debug LED
  478.  
  479. ; SCSI Interface (NCR 5380) for READ operations
  480. bSCSI    equ    $FFFF8780+REGBASE
  481. SCSIDB    equ    bSCSI+($00*REGSTEP)    ; current SCSI data bus
  482. SCSIICR    equ    bSCSI+($01*REGSTEP)    ; initiator command register
  483. SCSIMR    equ    bSCSI+($02*REGSTEP)    ; mode register
  484. SCSITCR    equ    bSCSI+($03*REGSTEP)    ; target command register
  485. SCSICR    equ    bSCSI+($04*REGSTEP)    ; current SCSI control register
  486. SCSIDSR    equ    bSCSI+($05*REGSTEP)    ; DMA status register
  487. SCSIIDR    equ    bSCSI+($06*REGSTEP)    ; input data register
  488. SCSIREI    equ    bSCSI+($07*REGSTEP)    ; reset error / interrupt
  489.  
  490. ; SCSI Interface (NCR 5380) for WRITE operations
  491. SCSIODR    equ    bSCSI+($00*REGSTEP)    ; output data register
  492. ;SCSIICR    bSCSI+($01*REGSTEP)    ; initiator command register
  493. ;SCSIMR        bSCSI+($02*REGSTEP)    ; mode register
  494. ;SCSITCR    bSCSI+($03*REGSTEP)    ; target command register
  495. SCSIISR    equ    bSCSI+($04*REGSTEP)    ; ID select register
  496. SCSIDS    equ    bSCSI+($05*REGSTEP)    ; start DMA send
  497. SCSIDTR    equ    bSCSI+($06*REGSTEP)    ; start DMS target receive
  498. SCSIDIR    equ    bSCSI+($07*REGSTEP)    ; start DMA initiator receive
  499.  
  500. ; SCSI DMA Controller
  501. bSDMAPTR    equ    $FFFF8701
  502. bSDMACNT    equ    $FFFF8709
  503. SDMARES    equ    $FFFF8710
  504. SDMACTL    equ    $FFFF8714    ; WORD
  505.  
  506. DMAOUT    equ    01
  507. DMAIN    equ    00
  508. DMAENA    equ    02
  509. DMADIS    equ    00
  510.  
  511. SCSIID    equ    6        ; our (host) SCSI ID
  512.  
  513.   .macro w4req
  514. .1\~:    btst    #5,SCSICR        ; waiting for REQ to come
  515.     beq.s    .1\~
  516.   .endm
  517.  
  518.   .macro doack
  519.     ori.b    #$11,SCSIICR        ; assert ACK (and data bus)
  520. .1\~:    btst    #5,SCSICR        ; wait for REQ to go away
  521.     bne.s    .1\~
  522.     andi.b    #$ef,SCSIICR        ; clear ACK
  523.   .endm
  524.  
  525.   .macro hshake    xbyte
  526.     w4req
  527.     move.b    \xbyte,SCSIDB        ; write a byte out to data bus
  528.     doack
  529.   .endm
  530.  
  531.   .macro w4irq
  532. .1\~:    btst    #5,GPIP
  533.     bne.s    .1\~
  534.   .endm
  535.  
  536.  
  537. scrw:    move.w    _retries,retrycnt    ; setup retry counter
  538. scrw0:    move.w    xdev(a6),d0    ; get the unit number
  539.     btst    #3,xrw+1(a6)    ; is this a physical operation?
  540.     beq.s    .0        ; no, so go get unit from pun
  541.     subi.w    #10,d0        ; subtract number of floppy&ACSI units
  542.     bra.s    .1        ; and use that as the unit number
  543.  
  544. .0:    lea    pun,a2
  545.     move.b    (a2,d0.w),d0    ; get the physical unit number
  546.     andi.w    #3,d0        ; strip off the flags
  547.  
  548. .1:    move.w    d0,-(sp)
  549.     bsr    selSCSI        ; select the SCSI device
  550.     addq    #2,sp
  551.  
  552.   .if SCDMA
  553.     move.l    xbuf(a6),d0    ; set the DMA source/destination
  554.     move.b    d0,bSDMAPTR+6
  555.     lsr.l    #8,d0
  556.     move.b    d0,bSDMAPTR+4
  557.     lsr.l    #8,d0
  558.     move.b    d0,bSDMAPTR+2
  559.     lsr.l    #8,d0
  560.     move.b    d0,bSDMAPTR
  561.  
  562. ; set up the size of the transfer (in bytes, assume each sector = $0200 bytes)
  563.     clr.l    d0
  564.     move.w    xcount(a6),d0    ; get the count of sectors
  565.     move.b    #0,bSDMACNT+6    ; lsb of byte cnt always 0
  566.     lsl.l    #1,d0        ; *$200/$100
  567.     move.b    d0,bSDMACNT+4
  568.     lsr.l    #8,d0
  569.     move.b    d0,bSDMACNT+2
  570.     lsr.l    #8,d0
  571.     move.b    d0,bSDMACNT
  572.   .endif ;SCDMA
  573.  
  574.     clr.l    d1
  575.     move.w    xrecno(a6),d1    ; get the record number
  576.     cmpi.w    #-1,d1        ; is recno==-1
  577.     bne.s    .11        ; if not, then use it
  578.     move.l    xlrecno(a6),d1    ; if so, then it implies the long form
  579. .11:    btst    #3,xrw+1(a6)    ; is it a physical operation?
  580.     bne.s    .15        ; yes, so don't change record number
  581.     move.w    xdev(a6),d2    ; get the logical unit number again
  582.     lsl.w    #2,d2        ; make it a long word index
  583.     lea    start,a2    ; and a pointer to the offset table
  584.     add.l    (a2,d2.w),d1    ; add the starting offset to specified record
  585. .15:
  586.   .if VERBOSE
  587.     movem.l    d0-d3/a0-a3,-(sp)
  588.     move.l    d1,-(sp)
  589.     bsr    crlf
  590.     move.b    #'R',d0
  591.     btst    #0,xrw+1(a6)
  592.     beq.s    .100
  593.     move.b    #'W',d0
  594. .100:    bsr    putc
  595.     move.w    retrycnt,d0
  596.     bsr    putnib
  597.     move.b    #':',d0
  598.     bsr    putc
  599.     move.w    xcount(a6),d0
  600.     bsr    putwor
  601.     move.b    #'#',d0
  602.     bsr    putc
  603.     move.l    (sp),d0
  604.     bsr    putlon
  605.     move.b    #'@',d0
  606.     bsr    putc
  607.     move.l    xbuf(a6),d0
  608.     bsr    putlon
  609.     move.l    (sp)+,d1
  610.     movem.l    (sp)+,d0-d3/a0-a3
  611.   .endif ;VERBOSE
  612.     move.b    #$28,d0        ; SCSI read extended command
  613.     btst    #0,xrw+1(a6)    ; read or write?
  614.     beq.s    .16
  615.     move.b    #$2A,d0        ; SCSI write extended command
  616. .16:    move.b    #2,SCSITCR    ; assert C/D
  617.     move.b    #1,SCSIICR    ; assert data bus
  618.     hshake    d0        ; write the command     -- 00 --
  619.     hshake    #0        ;                       -- 01 --
  620.     move.l    d1,d0        ; get the long block number
  621.     rol.l    #8,d0        ; send 4 bytes of block number
  622.     hshake    d0        ;                       -- 02 --
  623.     rol.l    #8,d0
  624.     hshake    d0        ;                       -- 03 --
  625.     rol.l    #8,d0
  626.     hshake    d0        ;                       -- 04 --
  627.     rol.l    #8,d0
  628.     hshake    d0        ;                       -- 05 --
  629.     hshake    #0        ; reserved byte         -- 06 --
  630.     move.w    xcount(a6),d0    ; word of count
  631.     rol.w    #8,d0
  632.     hshake    d0        ;                       -- 07 --
  633.     rol.w    #8,d0
  634.     hshake    d0        ;                       -- 08 --
  635.   .if 0
  636.     bra    .18        ; go send the control byte
  637.  
  638. ; send the SCSI command to the device
  639. .0:    move.b    #$08,d0        ; SCSI read command
  640.     btst    #0,xrw+1(a6)    ; only use lsb here, others reserved
  641.     beq.s    .1
  642.     move.b    #$0a,d0        ; SCSI write command
  643. .1:    move.b    #2,bSCSI+(3*REGSTEP)    ; assert c/d
  644.     move.b    #1,bSCSI+(1*REGSTEP)    ; assert data bus
  645.     hshake    d0        ; write the command     -- 00 --
  646.     hshake    #0        ; unfortunately rwabs only uses word block num
  647.     move.w    xrecno(a6),d0    ; get the specified block number
  648.     lsr.w    #8,d0
  649.     hshake    d0        ;                       -- 02 --
  650.     move.w    xrecno(a6),d0
  651.     hshake    d0        ;                       -- 03 --
  652.     move.w    xcount(a6),d0
  653.     hshake    d0        ;                       -- 04 --
  654.   .endif ;0
  655. .18:    hshake    #0        ; control byte always 0 -- 05 -- or -- 09 --
  656.  
  657.     btst    #0,xrw+1(a6)    ; only use lsb here, others reserved
  658.     beq.s    .25
  659.  
  660. ; write
  661.   .if SCDMA
  662.     move.b    #0,SCSITCR        ; set data out phase
  663.     move.b    SCSIREI,d0        ; clear potential interrupt
  664.     move.b    #2,SCSIMR        ; enable DMA mode
  665.     move.b    #0,SCSIDS        ; start the DMA send
  666.     move.w    #DMAOUT,SDMACTL        ; set the DMAC direction
  667.     move.w    #DMAOUT+DMAENA,SDMACTL    ; turn on DMAC
  668.     bra.s    .26
  669.   .else ;SCDMA
  670.     movea.l    #bSCSI,a0        ; pointer to the 5380
  671.     move.b    #0,3*REGSTEP(a0)    ; set data out phase
  672.     move.b    7*REGSTEP(a0),d0    ; clear potential interrupt
  673.     movea.l    xbuf(a6),a1        ; buffer pointer
  674.  
  675. .22:    btst    #5,4*REGSTEP(a0)    ; wait for REQ
  676.     beq.s    .22
  677.     btst    #3,5*REGSTEP(a0)    ; still in right phase
  678.     beq.s    .3            ; no, end of data out phase
  679.     move.b    (a1)+,(a0)        ; write the data byte
  680.  
  681.     bset    #4,1*REGSTEP(a0)    ; assert ACK
  682.  
  683. .23:    btst    #5,4*REGSTEP(a0)    ; wait for REQ to go away
  684.     bne.s    .23
  685.  
  686.     bclr    #4,1*REGSTEP(a0)    ; clear ACK
  687.     bra.s    .22
  688.   .endif ;SCDMA
  689.  
  690. ; read
  691. .25:
  692.   .if SCDMA
  693.     move.b    #0,SCSIICR        ; deassert the data bus
  694.     move.b    #1,SCSITCR        ; set data in phase
  695.     move.b    SCSIREI,d0        ; clear potential interrupt
  696.     move.b    #2,SCSIMR        ; enable DMA mode
  697.     move.b    #0,SCSIDIR        ; start the DMA receive
  698.     move.w    #DMAIN,SDMACTL        ; set the DMAC direction
  699.     move.w    #DMAIN+DMAENA,SDMACTL    ; turn on DMAC
  700.  
  701. .26:    btst    #GPIP2SCSI,GPIP2    ; wait for 5380 to interrupt
  702.     bne.s    .261            ; active HIGH
  703.     btst    #5,GPIP2        ; or for DMAC to interrupt
  704.     bne.s    .26            ; active LOW
  705.     move.w    SDMACTL,d0        ; get the DMA status
  706.     andi.l    #$80,d0            ; ignore countout ints
  707.     beq.s    .26
  708.     neg.l    d0
  709.     move.l    d0,-(sp)
  710.     bsr    resetSCSI
  711.     move.l    (sp)+,d0
  712.     bra    .99
  713.  
  714. .261:    move.b    SCSIREI,d0        ; clear potential interrupt
  715.  
  716. ; disable DMA
  717.     move.w    #DMADIS,SDMACTL
  718.  
  719.     move.b    #0,SCSIMR        ; disable DMA mode
  720.     move.b    #0,SCSIICR        ; make sure data bus is not asserted
  721.   .else ;SCDMA
  722.     movea.l    #bSCSI,a0        ; pointer to the 5380
  723.     move.b    #1,3*REGSTEP(a0)    ; set data in phase
  724.     move.b    7*REGSTEP(a0),d0    ; clear potential interrupt
  725.     movea.l    xbuf(a6),a1        ; buffer pointer
  726.  
  727. .27:    btst    #5,4*REGSTEP(a0)    ; wait for REQ
  728.     beq.s    .27
  729.     btst    #3,5*REGSTEP(a0)    ; still in right phase
  730.     beq.s    .3            ; no, end of data in phase
  731.     move.b    (a0),(a1)+        ; read the data byte
  732.  
  733.     bset    #4,1*REGSTEP(a0)    ; assert ACK
  734.  
  735. .28:    btst    #5,4*REGSTEP(a0)    ; wait for REQ to go away
  736.     bne.s    .28
  737.  
  738.     bclr    #4,1*REGSTEP(a0)    ; clear ACK
  739.     bra.s    .27
  740.  
  741.   .endif ;SCDMA
  742.  
  743. .3:    move.b    #3,SCSITCR        ; status in phase
  744.     move.b    SCSIREI,d0        ; clear potential interrupt
  745.  
  746.     w4req                ; wait for status byte
  747.     clr.w    d0
  748.     move.b    bSCSI,d0
  749.     move.w    d0,-(sp)
  750.     doack
  751.  
  752.     w4req
  753.     move.b    bSCSI,d0        ; get and ignore message byte
  754.     doack
  755.  
  756.   .if VERBOSE
  757.     move.b    #'^',d0
  758.     bsr    putc
  759.     move.w    (sp),d0
  760.     bsr    putbyt
  761.   .endif ;VERBOSE
  762.  
  763.     btst    #0,xrw+1(a6)    ; only use lsb here, others reserved
  764.     bne.s    .9        ; if this was a write, we are done
  765.  
  766.     move.b    bSDMAPTR+6,d0    ; see if this was an odd transfer
  767.  
  768.     andi.w    #3,d0
  769.     beq.s    .9        ; no, nice and even (and easy)
  770.  
  771.     move.b    bSDMAPTR+0,d0
  772.     lsl.l    #8,d0
  773.     move.b    bSDMAPTR+2,d0
  774.     lsl.l    #8,d0
  775.     move.b    bSDMAPTR+4,d0
  776.     lsl.l    #8,d0
  777.     move.b    bSDMAPTR+6,d0
  778.     move.l    d0,d1
  779.     andi.w    #3,d0
  780.  
  781.     andi.w    #$FFFF-3,d1    ; where does the data go?
  782.     movea.l    d1,a0
  783.     move.l    SDMARES,d1    ; get the residue
  784.     subq.w    #1,d0        ; dbra likes one less than count
  785. .8:    rol.l    #8,d1
  786.     move.b    d1,(a0)+
  787.     dbra    d0,.8
  788. .9:    clr.l    d0
  789.  
  790.     move.w    (sp)+,d0    ; recall the status byte
  791.     beq.s    .99
  792.     neg.l    d0        ; errors are negative numbers
  793.     subq.w    #1,retrycnt    ; drop retry count and retry
  794.     bpl    scrw0        ; if there are still chances to win
  795.  
  796. .99:    bra    ahrw7
  797.  
  798. *+
  799. * VOID resetSCSI();
  800. *-
  801.  
  802. resetSCSI:
  803.     move.b    #$80,SCSIICR    ; assert RST
  804.     movea.l    #_hz_200,a0
  805.     move.l    (a0),d0
  806.     addi.l    #51,d0        ; wait (at least) 250 mS
  807. .0:    cmp.l    (a0),d0
  808.     bne.s    .0
  809.     move.b    #$00,SCSIICR
  810.     move.l    (a0),d0
  811.     addi.l    #201,d0        ; wait (at least) 1000 mS
  812. .1:    cmp.l    (a0),d0
  813.     bne.s    .1
  814.     rts
  815.  
  816. *+
  817. * BOOLEAN selSCSI(SCSIUnit) WORD SCSIUnit;
  818. *-
  819.  
  820. selSCSI:
  821. .0:    btst    #6,SCSICR        ; not STILL busy from last time?
  822.     bne.s    .0
  823.  
  824.     move.b    #0,SCSITCR        ; data out phase
  825.     move.b    #0,SCSIISR        ; no interrupt from selection
  826.     move.b    #$0c,SCSIICR        ; assert BSY and SEL
  827. ; set dest SCSI IDs
  828.     clr.w    d0
  829.     move.w    4(sp),d1        ; get the SCSI unit desired
  830.     bset    d1,d0            ; set the appropriate bit
  831.     move.b    d0,SCSIODR        ; (real code would set ours too)
  832.  
  833.     move.b    #$0d,SCSIICR        ; assert BUSY, SEL and data bus
  834.  
  835.     andi.b    #$FE,SCSIMR        ; clear arbitrate bit
  836.     andi.b    #$F7,SCSIICR        ; clear BUSY
  837.     nop
  838.     nop
  839.  
  840. .1:    btst    #6,SCSICR        ; wait for bus to be busy
  841.     beq    .1
  842.  
  843.     move.b    #$0,SCSIICR        ; clear SEL and data bus assertion
  844.     clr.w    d0            ; note lack of SCSI device timeout
  845.     rts
  846.  
  847.   .endif ;SCSI
  848.  
  849.   .if VERBOSE
  850. ;
  851. ;    putlon - put d0.l as 8 hex digits
  852. ;    putwor - put d0.w as 4 hex digits
  853. ;    putbyt - put d0.b as 2 hex digits
  854. ;    putnib - put 4 lsbs as a hex digit
  855.  
  856. putlon:    move.l    d0,-(sp)
  857.     swap    d0
  858.     bsr    putwor
  859.     move.l    (sp)+,d0
  860. putwor:    move    d0,-(sp)
  861.     asr    #8,d0
  862.     bsr    putbyt
  863.     move    (sp)+,d0
  864. putbyt:    move    d0,-(sp)
  865.     asr    #4,d0
  866.     bsr    putnib
  867.     move    (sp)+,d0
  868. putnib:    andi.b    #$0f,d0
  869.     addi.b    #'0',d0
  870.     cmpi.b    #'9',d0
  871.     ble    putb2
  872.     addi.b    #7,d0
  873. putc:
  874. putb2:    tst.b    TSR
  875.     bpl.s    putb2
  876.     move.b    d0,UDR
  877.     rts
  878.  
  879. crlf:    move.l    #crlfmsg,-(sp)
  880.     bsr    puts
  881.     addq    #4,sp
  882.     rts
  883.  
  884. puts:    movea.l    4(sp),a0
  885. .1:    move.b    (a0)+,d0
  886.     beq.s    .9
  887.     bsr    putc
  888.     bra.s    .1
  889. .9:    rts
  890.  
  891. crlfmsg: dc.b    13,10,0
  892.     .even
  893.   .endif ;VERBOSE
  894.  
  895. * page 
  896. *+
  897. * _do_rw - called to read/write no more than 128K to an even boundary
  898. *
  899. * Passed:    dev    $e(sp).W
  900. *        recno    $c(sp).W
  901. *        count    $a(sp).W
  902. *        buf    6(sp).L
  903. *        rw    4(sp).W        ; non-zero -> write
  904. *
  905. *-
  906.     .globl    _do_rw
  907. _do_rw:
  908.     move.w    d3,-(sp)        ; preserve d3
  909.  
  910. sasrw0:    move.w    _retries,retrycnt    ; setup retry counter
  911.  
  912.     move.w    6(sp),d3
  913.     btst    #2,d3            ; are retries disabled?
  914.     beq    sasrw1            ; no, act normally
  915.     move.w    #0,retrycnt        ; yes, so set retrycnt to zero
  916.  
  917. *
  918. * read sector(s),
  919. * delay .0005 to .001 seconds between driver calls
  920. *
  921. sasrw1:
  922.     move.l    lastrwtm,d0
  923. sasrw8:    cmp.l    _hz_200,d0        ; while (_hz_200 <= lastrwtm)
  924.     bcc    sasrw8            ;    just_wait;
  925.     move.l    _hz_200,d0        ; lastrwtm = _hz_200 + 1;
  926.     addq.l    #1,d0
  927.     move.l    d0,lastrwtm
  928.  
  929.     lea    2(sp),a1        ; frame pointer
  930.     moveq    #0,d0            ; coerce word to long, unsigned
  931.     move.w    $c(a1),d0        ; sect.L
  932.     move.w    4(a1),d3        ; rw
  933.  
  934.     btst    #3,d3            ; physical unit operation
  935.     beq    sasrw2            ; no, so do log->phys mapping
  936.  
  937.     move    $0e(a1),d2        ; get unit number
  938.     subq    #2,d2            ; subtract drive C offset
  939.     bra    sasrw3            ; and use that as the physical unit
  940.  
  941. sasrw2:    clr    d2            ; coerce byte to word
  942.     move.w    $e(a1),d1        ; get device
  943.     lea    pun,a2
  944.     move.b    0(a2,d1.w),d2        ; get physical unit number
  945. sasrw3:    move.w    d2,-(sp)        ; dev
  946.     move.l    6(a1),-(sp)        ; buf
  947.     move.w    $a(a1),-(sp)        ; count
  948.  
  949.     btst    #3,d3            ; physical operation?
  950.     bne    sasrw4            ; yes, so no offset
  951.  
  952.     asl.w    #2,d1            ; *4 to get index into long array
  953.     lea    start,a2
  954.     add.l    0(a2,d1.w),d0        ; adjust sector number
  955.  
  956. sasrw4:    move.l    d0,-(sp)        ; sect
  957.     btst    #0,d3            ; read or write?
  958.     bne    sasrw5            ; (write)
  959.     bsr    _hread            ; read sectors
  960.     bra    sasrw6
  961. sasrw5:    bsr    _hwrite            ; write sectors
  962. sasrw6:    add.w    #12,sp            ; (cleanup stack)
  963.     tst.l    d0            ; errors?
  964.     beq    sasrwr            ; no -- success
  965.     subq.w    #1,retrycnt        ; drop retry count and retry
  966.     bpl    sasrw1
  967.  
  968.     move    6(sp),d1        ; get r/w and flags word
  969.     move.l    #EREADF,d0        ; read error code
  970.     btst    #0,d1
  971.     beq    sasrw7
  972.     move.l    #EWRITF,d0        ; write error code
  973.  
  974. sasrw7:    btst    #2,d1            ; is this a "raw" operation?
  975.     bne    sasrwr            ; yes, so no critical error handler
  976.  
  977.     move.w    $10(sp),-(sp)        ; unit number
  978.     move.w    d0,-(sp)        ; error code (as a word, sic)
  979.     movea.l    etv_critic,a0
  980.     jsr    (a0)
  981.     addq    #4,sp
  982.     cmpi.l    #CRITRETRY,d0        ; is it the magic RETRY code?
  983.     beq    sasrw0
  984.  
  985. sasrwr:    move.w    (sp)+,d3        ; remember to restore d3
  986.     rts
  987.  
  988. *+
  989. * _sasi_mediach - see if hard disk media has changed (it never does)
  990. * Synopsis:    _sasi_mediach(dev)
  991. *        WORD dev;
  992. *
  993. * Returns:    0L
  994. *
  995. *-
  996.     .globl    _sasi_mediach
  997. _sasi_mediach:
  998.     clr.l    d0
  999.     rts
  1000.  
  1001.  
  1002. * page 
  1003. * ---------------- Low-level driver ----------------
  1004.  
  1005.  
  1006. *----- Hardware:
  1007. wdc        equ    $ffff8604
  1008. wdl        equ    $ffff8606
  1009. wdcwdl        equ    wdc        ; used for long writes
  1010. xwdl        equ    wdl-wdc        ; offset from wdc to wdl
  1011.  
  1012. dmahi        equ    $ffff8609
  1013. dmamid        equ    dmahi+2
  1014. dmalow        equ    dmamid+2
  1015. gpip        equ    $fffffa01
  1016.  
  1017.  
  1018. *----- Tunable:
  1019. ltimeout        equ    450000        ; long-timeout (3 S)
  1020. stimeout        equ    15000        ; short-timeout (100 mS)
  1021.  
  1022. *+
  1023. * LONG _qdone() - Wait for command byte handshake
  1024. * LONG _fdone() - Wait for operation complete
  1025. * Passed:    nothing
  1026. *
  1027. * Returns:    EQ: no timeout
  1028. *        MI: timeout condition
  1029. *
  1030. * Uses:        D0
  1031. *
  1032. * each pass through the loop takes 6.75 uS
  1033. *-
  1034.     .if    sermsg
  1035.  
  1036. _fdone:    move    d1,-(sp)
  1037.     move    #1,d1
  1038.     move.l    #ltimeout,tocount
  1039.     bra    qd1
  1040.  
  1041. _qdone:
  1042.     move    d1,-(sp)
  1043.     move    #0,d1
  1044.     move.l    #stimeout,tocount
  1045. qd1:    subq.l    #1,tocount        ; drop timeout count
  1046.     bmi    qdq            ; (i give up, return NE)
  1047.     btst    #5,gpip            ; interrupt?
  1048.     bne    qd1            ; (not yet)
  1049.  
  1050.     move    (sp)+,d1
  1051.     moveq    #0,d0            ; return EQ (no timeout)
  1052.     rts
  1053.  
  1054. qdq:    nop
  1055.  
  1056.     .if    1
  1057.  
  1058.     movem.l    d0-d3/a0-a4,-(sp)
  1059.     lea    stmsg,a4
  1060.     tst    d1
  1061.     beq    qdq1
  1062.     lea    ltmsg,a4
  1063. qdq1:    move.b    (a4)+,d0
  1064.     beq    qdq2
  1065.     move    d0,-(sp)
  1066.     move    #1,-(sp)
  1067.     move    #3,-(sp)
  1068.     trap    #13
  1069.     addq    #6,sp
  1070.     bra    qdq1
  1071.  
  1072. qdq2:    movem.l    (sp)+,d0-d3/a0-a4
  1073.  
  1074.     .endif
  1075.  
  1076.     move    (sp)+,d1
  1077.     moveq    #-1,d0
  1078.     rts
  1079.  
  1080. stmsg:    dc.b    'Short timeout',$0d,$0a,0
  1081. ltmsg:    dc.b    'Long timeout',$0d,$0a,0
  1082. drmsg:    dc.b    $0d,$0a,'Drive ',0
  1083.     even
  1084.  
  1085.     .endif
  1086.  
  1087.     .if    sermsg=0
  1088.  
  1089. _fdone:    move.l    #ltimeout,tocount
  1090.     bra    qd1
  1091.  
  1092. _qdone:
  1093.     move.l    #stimeout,tocount
  1094. qd1:    subq.l    #1,tocount        ; drop timeout count
  1095.     bmi    qdq            ; (i give up, return NE)
  1096.     btst    #5,gpip            ; interrupt?
  1097.     bne    qd1            ; (not yet)
  1098.  
  1099.     moveq    #0,d0            ; return EQ (no timeout)
  1100.     rts
  1101.  
  1102. qdq:    moveq    #-1,d0
  1103.     rts
  1104.  
  1105.     .endif
  1106.  
  1107. *+
  1108. * WORD _endcmd()
  1109. * Wait for end of SASI command
  1110. * Passed:    d0 value to be written to wdl
  1111. *
  1112. * Returns:    EQ: success (error code in D0.W)
  1113. *        MI: timeout
  1114. *        NE: failure (SASI error code in D0.W)
  1115. *
  1116. * Uses:        d0,d1
  1117. *-
  1118. _endcmd: move    d0,d1            ; preserve wdl value
  1119.  
  1120.     bsr    _fdone            ; wait for operation complete
  1121.     bmi    endce            ; (timed-out, so complain)
  1122.  
  1123.     move.w    d1,wdl
  1124.     nop
  1125.     move.w    wdc,d0            ; get the result
  1126.     and.w    #$00ff,d0        ; (clean it up), if non-zero should
  1127.  
  1128. endce:    rts                ;  do a ReadSense command to learn more
  1129.  
  1130. *-
  1131. * _hread(sectno, count, buf, dev)
  1132. * LONG sectno;         4(sp)
  1133. * WORD count;         8(sp)
  1134. * LONG buf;        $a(sp)    $b=high, $c=mid, $d=low
  1135. * WORD dev;        $e(sp)
  1136. *
  1137. * Returns:    -1 on timeout
  1138. *        0 on success
  1139. *        nonzero on error
  1140. *
  1141. *-
  1142.     .globl    _hread
  1143. _hread:
  1144.     movea.l    #wdc,a0            ; pointer to DMA chip
  1145.     st    flock            ; lock FIFO
  1146.  
  1147.     move    #$88,xwdl(a0)
  1148.     clr.l    d0
  1149.     move.w    $0e(sp),d0        ; get unit number
  1150.     lsl.w    #5,d0
  1151.     swap    d0
  1152.     ori.l    #$0008008a,d0        ; 08 wdc, 8a wdl
  1153.     move.l    d0,(a0) ; wdcwdl
  1154.  
  1155.     move.l    $a(sp),-(sp)        ; set DMA address
  1156.     bsr    _setdma
  1157.     addq    #4,sp
  1158.  
  1159.     bsr    _setss            ; set sector and size
  1160.     bmi    _hto
  1161.  
  1162.     move.w    #$190,xwdl(a0)
  1163.     nop
  1164.     move.w    #$90,xwdl(a0)
  1165.     nop
  1166.     move.w    8(sp),(a0) ;wdc        ; write sector count to DMA chip
  1167.     nop
  1168.     move.w    #$8a,xwdl(a0)
  1169.     nop
  1170.     move.l    #$00000000,(a0) ; wdcwdl; control byte  0 wdc 0 wdl
  1171.  
  1172.     move.w    #$8a,d0
  1173.     bsr    _endcmd
  1174.  
  1175. hrx:    bra    _hdone            ; cleanup after IRQ
  1176.  
  1177.  
  1178. *-
  1179. * _hwrite(sectno, count, buf, dev)
  1180. * LONG sectno;         4(sp)
  1181. * WORD count;         8(sp)
  1182. * LONG buf;        $a(sp)    $b=high, $c=mid, $d=low
  1183. * WORD dev;        $e(sp)
  1184. *
  1185. *-
  1186.     .globl    _hwrite
  1187. _hwrite:
  1188.     movea.l    #wdc,a0            ; pointer to DMA chip
  1189.     st    flock            ; lock FIFO
  1190.  
  1191.     move.l    $a(sp),-(sp)        ; set DMA address
  1192.     bsr    _setdma
  1193.     addq    #4,sp
  1194.  
  1195.     move.w    #$88,xwdl(a0)
  1196.     clr.l    d0
  1197.     move.w    $0e(sp),d0        ; get unit number
  1198.     lsl.w    #5,d0
  1199.     swap    d0
  1200.     ori.l    #$000a008a,d0        ; 0a wdc 8a wdl
  1201.     move.l    d0,(a0) ; wdcwdl
  1202.  
  1203.     bsr    _setss
  1204.     bmi    _hto
  1205.  
  1206.     move.w    #$90,xwdl(a0)
  1207.     nop
  1208.     move.w    #$190,xwdl(a0)
  1209.     nop
  1210.     move.w    8(sp),(a0) ;wdc        ; sector count for DMA chip's benefit
  1211.     nop
  1212.     move.w    #$18a,xwdl(a0)
  1213.     nop
  1214.     move.l    #$00000100,(a0) ; wdcwdl
  1215.  
  1216.     move.w    #$18a,d0
  1217.     bsr    _endcmd
  1218.  
  1219. hwx:    bra    _hdone            ; cleanup after IRQ
  1220.  
  1221.  
  1222. *+
  1223. * void _setdma(addr)
  1224. * LONG addr;
  1225. *-
  1226. _setdma:
  1227.     move.b    7(sp),dmalow
  1228.     move.b    6(sp),dmamid
  1229.     move.b    5(sp),dmahi
  1230.     rts
  1231.  
  1232. *+
  1233. * WORD _setss  -- set sector number and number of sectors
  1234. *-
  1235.  
  1236. _setss:    move.w    #$8a,xwdl(a0)
  1237.  
  1238.     bsr    _qdone            ; wait for controller to take command
  1239.     bmi    setsse
  1240.  
  1241.     move.b    9(sp),d0        ; construct sector#
  1242.     swap    d0
  1243.     move.w    #$008a,d0
  1244.     move.l    d0,(a0) ; wdcwdl    ; write MSB sector# + devno
  1245.     bsr    _qdone
  1246.     bmi    setsse
  1247.  
  1248.     move.b    10(sp),d0        ; write MidSB sector#
  1249.     swap    d0
  1250.     move.w    #$008a,d0
  1251.     move.l    d0,(a0) ; wdcwdl
  1252.     bsr    _qdone
  1253.     bmi    setsse
  1254.  
  1255.     move.b    11(sp),d0        ; write LSB sector#
  1256.     swap    d0
  1257.     move.w    #$008a,d0
  1258.     move.l    d0,(a0) ; wdcwdl
  1259.     bsr    _qdone
  1260.     bmi    setsse
  1261.  
  1262.     move.w    12(sp),d0        ; write sector count
  1263.     swap    d0
  1264.     move.w    #$008a,d0
  1265.     move.l    d0,(a0) ; wdcwdl
  1266.     bsr    _qdone
  1267.  
  1268. setsse:    rts
  1269.  
  1270. _hto:    moveq    #-1,d0        ; indicate timeout
  1271. _hdone:    move.w    #$80,wdl    ; Landon's code seems to presume we
  1272.     nop            ;  put this back to $80
  1273.     tst.w    wdc
  1274.     clr    flock        ; NOW, signal that we are done
  1275.     rts
  1276.  
  1277. isasi5:
  1278.   .if ospool
  1279.     bsr    pool_install    ; attempt to install more OS pool
  1280.   .endif
  1281.     move.l    d0,-(sp)    ; preserve the number of bytes we need
  1282.  
  1283.     tst.w    bootloaded    ; if bootloaded, then already in super mode
  1284.     bne    nboot1        ; (already there)
  1285.     move.l    savssp,-(sp)    ; become a mild mannered user process
  1286.     move.w    #$20,-(sp)    ; Super(savssp)
  1287.     trap    #1
  1288.     addq    #6,sp
  1289.  
  1290. nboot1:    move.l    (sp)+,d0    ; compute value for Ptermres() or Mshrink
  1291.     add.l    #((i_sasi1-i_sasi)+$0100),d0
  1292.  
  1293.     tst.w    bootloaded    ; exit to GEMDOS?
  1294.     beq    nboot2        ; (yes -- not boot loaded)
  1295.  
  1296. *
  1297. *  Return to TOS ROMs
  1298. *    - set default boot device to C:
  1299. *    - Print silly message
  1300. *    - Mshrink() memory that was alloc'd to us
  1301. *    - set magic# in D7 for TOS ROMs
  1302. *    - RTS back to ROMs
  1303. *
  1304.     move.l    d0,-(sp)    ; save D0
  1305.     pea    msg_loaded(pc)    ; print announcement
  1306.     move.w    #9,-(sp)
  1307.     trap    #1
  1308.     addq    #6,sp
  1309.     move.l    (sp)+,d0
  1310.  
  1311.     move.w    #2,_bootdev    ; set default boot device to C: (devno=2)
  1312.     move.l    d0,-(sp)
  1313.     move.l    baseaddr,-(sp)
  1314.     clr.w    -(sp)
  1315.     move.w    #$4a,-(sp)    ; Mshrink(...)
  1316.     trap    #1
  1317.     add.w    #12,sp        ; (cleanup stack)
  1318.  
  1319.  
  1320. exec_os        equ    $4fe
  1321.  
  1322. *+
  1323. *  Bring up the AES:
  1324. *    do autoexec;
  1325. *    construct an enviroment string;
  1326. *    create a basepage for the AES;
  1327. *    exec the AES.
  1328. *
  1329. *-
  1330. st_1:
  1331.     bsr    findpackages        ; find bootable RAM packages
  1332.     bsr    _auto            ; do auto-exec
  1333.  
  1334.     pea    orig_env        ; push address of enviroment string
  1335.     pea    nullenv(pc)        ; no arguments
  1336.     pea    nullenv(pc)        ; null shell name (in ROM, after all)
  1337.     move.w    #5,-(sp)        ; createPSP flavor of exec
  1338.     move.w    #$4b,-(sp)        ; exec function#
  1339.     trap    #1            ; get pointer to PSP
  1340.     add.w    #14,sp            ; (clean up cruft)
  1341.     move.l    d0,a0            ; a0 -> PSP
  1342.     move.l    exec_os,8(a0)        ; stuff saddr of GEM in PSP
  1343.  
  1344.     move.l    a0,-(sp)        ; push addr of PSP
  1345.     pea    nullenv(pc)        ; null filename
  1346.     move.w    #4,-(sp)        ; just-go
  1347.  
  1348. st_x:    move.w    #$4b,-(sp)        ; function = exec
  1349.     trap    #1            ; do it
  1350.     add.w    #14,sp            ; cleanup stack
  1351.  
  1352. *+
  1353. * When startup fails (or if the exec returns,
  1354. * which "cannot happen") fake a system reset:
  1355. *-
  1356.     move.l    4,a0            ; get RESET vector
  1357.     jmp    (a0)            ; and do it
  1358.  
  1359.  
  1360.  
  1361. *+
  1362. * Default enviroment string
  1363. *
  1364. *-
  1365. orig_env:
  1366.     dc.b    "PATH=",0        ; default pathname
  1367.     dc.b    "C:\\",0        ; is the boot device
  1368.     dc.b    0            ; terminate env string
  1369.  
  1370.  
  1371. gemname: dc.b    "GEM.PRG"        ; desktop name
  1372. nullenv: dc.b    0,0            ; null string (and enviroment)
  1373.     even
  1374.  
  1375.  
  1376. *+
  1377. *  Auto path for hard disks (C:)
  1378. *
  1379. *-
  1380. autopath:    dc.b    'C:\\AUTO\\'
  1381. autofile:    dc.b    '*.PRG',0
  1382.         dc.w    $1234,$5678,$9abc,$def0
  1383.     even
  1384.  
  1385.  
  1386. *+
  1387. * _auto - exec auto-startup files in the appropriate subdirectory
  1388. * _auto1 - exec (with filename args)
  1389. *
  1390. * Passed:    a0 -> full filespec (pathname)
  1391. *        a1 -> filename part of filespec
  1392. *
  1393. * Returns:    nothing
  1394. *
  1395. * Uses:        everything
  1396. *-
  1397.     .globl    _auto            ; for debugging
  1398. _auto:    lea    autopath(pc),a0        ; -> path
  1399.     lea    autofile(pc),a1        ; -> filename
  1400.  
  1401. _auto1:    move.l    (sp)+,autoret        ; copy return addr (used by execlr)
  1402.     move.l    sp,origstk        ; (save original stack)
  1403.     move.l    a0,pathname        ; setup filename/pathname ptrs
  1404.     move.l    a1,filename
  1405.  
  1406.     lea    nullenv(pc),a3        ; a0 -> \0\0
  1407.     move.l    a3,-(sp)        ; null enviroment
  1408.     move.l    a3,-(sp)        ; null command tail
  1409.     move.l    a3,-(sp)        ; null shell name
  1410.     move.w    #5,-(sp)        ; Create-PSP subfunction
  1411.     move.w    #$4b,-(sp)        ; exec function#
  1412.     trap    #1            ; do DOS call
  1413.     add.w    #16,sp
  1414.  
  1415.     move.l    d0,a0            ; a0 -> PSP
  1416.     move.l    #fauto,8(a0)        ; initial PC -> autoexec prog
  1417.  
  1418.     move.l    a3,-(sp)        ; null enviroment
  1419.     move.l    d0,-(sp)        ; -> PSP
  1420.     move.l    a3,-(sp)        ; null shell name
  1421.     move.w    #4,-(sp)        ; just-go
  1422.     move.w    #$4b,-(sp)        ; function = exec
  1423.     trap    #1            ; do it
  1424.     add.w    #16,sp            ; cleanup stack & goodbye
  1425. autoq:    move.l    autoret,-(sp)
  1426.     rts
  1427.  
  1428.  
  1429.  
  1430. *+
  1431. *  fauto - exec'd by _auto to do autostartup
  1432. *
  1433. *  Passed:    pathname -> path part of filespec
  1434. *        filename -> file part of filespec
  1435. *
  1436. *-
  1437. fauto:
  1438.     move.w    #2,-(sp)        ; Dsetdrv(2)
  1439.     move.w    #$e,-(sp)
  1440.     trap    #1
  1441.     addq    #4,sp
  1442.  
  1443.     clr.l    -(sp)            ; get into super mode
  1444.     move.w    #$20,-(sp)
  1445.     trap    #1
  1446.     addq    #6,sp            ; cleanup
  1447.     move.l    d0,a4            ; a4 -> saved super stack
  1448.  
  1449. *--- free up some memory:
  1450.     move.l    4(a7),a5        ; a5 -> base page
  1451.     lea    $100(a5),sp        ; sp -> new, safer addr
  1452.     move.l    #$100,-(sp)        ; keep $100 (just the basepage)
  1453.     move.l    a5,-(sp)        ; -> start of mem to keep
  1454.     clr.w    -(sp)            ; junk word
  1455.     move.w    #$4a,-(sp)        ; setblock(...)
  1456.     trap    #1
  1457.     addq    #6,sp
  1458.     tst.w    d0
  1459.     bne    au_dn            ; punt on error
  1460.  
  1461.     move.w    #$0007,-(sp)        ; find r/o+hidden+system files
  1462.     move.l    pathname,-(sp)        ; -> filename (on input)
  1463.     move.w    #$4e,-(sp)        ; searchFirst
  1464.  
  1465.     moveq    #8,d7            ; d7 = cleanup amount
  1466. au1:    pea    autodma            ; setup DTA (for search)
  1467.     move.w    #$1a,-(sp)
  1468.     trap    #1
  1469.     addq    #6,sp
  1470.  
  1471.     trap    #1            ; search first/search next
  1472.     add.w    d7,sp            ; cleanup stack
  1473.     tst.w    d0            ; test for match
  1474.     bne    au_dn            ; (no match -- quit)
  1475.  
  1476. *--- construct filename from path and the name we just found:
  1477.     move.l    pathname,a0        ; copy pathname
  1478.     move.l    filename,a2        ; a2 -> end+1 of pathname
  1479.     lea    autoname,a1
  1480. au3:    move.b    (a0)+,(a1)+        ; copy path part of name
  1481.     cmp.l    a0,a2            ; finished?
  1482.     bne    au3            ; (no)
  1483.     lea    autodma+30,a0        ; copy fname to end of pathname
  1484. au2:    move.b    (a0)+,(a1)+
  1485.     bne    au2
  1486.  
  1487.     pea    nullenv(pc)        ; null enviroment
  1488.     pea    nullenv(pc)        ; no command tail
  1489.     pea    autoname        ; -> file to exec
  1490.     clr.w    -(sp)            ; load-and-go
  1491.     move.w    #$4b,-(sp)        ; exec(...)
  1492.     trap    #1
  1493.     add.w    #16,sp
  1494.  
  1495.     moveq    #2,d7            ; reset cleanup amount
  1496.     move.w    #$4f,-(sp)        ; searchNext
  1497.     bra    au1
  1498.  
  1499. *+
  1500. * Search for a package, execute it.
  1501. *
  1502. *    +---------------+
  1503. *    |   $12123456    | base + 0, on a 512-byte boundary
  1504. *    |        |
  1505. *    +---------------+
  1506. *    |   -> base    | base + 4
  1507. *    |        |
  1508. *    +---------------+
  1509. *    |   (code)    | base + 8
  1510. *    /        /
  1511. *    /        /
  1512. *    |        |
  1513. *    +---------------+
  1514. *              base + 512
  1515. *
  1516. *    The entire 512-byte block should word-checksum to $5678.
  1517. *
  1518. *-
  1519. findpackages:
  1520.     move.l    phystop,a0        ; a0 -> top of memory
  1521. fpk_n:    sub.w    #512,a0            ; down 512 bytes
  1522.     cmp.l    #$400,a0        ; bottom of memory?
  1523.     beq    fpk_r            ; (yes -- punt)
  1524.     cmp.l    #$12123456,(a0)        ; check magic #
  1525.     bne    fpk_n            ; (no match, try next one)
  1526.     cmp.l    4(a0),a0        ; self-pointer?
  1527.     bne    fpk_n            ; (doesn't point to itself, retry)
  1528.  
  1529.     clr.w    d0            ; zero checksum reg
  1530.     move.l    a0,a1            ; a1 -> block to checksum
  1531.     move.w    #$ff,d1            ; do 256 words
  1532. fpk_1:    add.w    (a1)+,d0        ; sum a word
  1533.     dbra    d1,fpk_1        ;    ... until we're done
  1534.     cmp.w    #$5678,d0        ; magic number to exec()?
  1535.     bne    fpk_n            ; (no, retry)
  1536.     move.l    a0,-(sp)        ; save our precious package pointer
  1537.     jsr    8(a0)            ; call package's code
  1538.     move.l    (sp)+,a0        ; restore A0
  1539.     bra    fpk_n            ; (do more blocks)
  1540.  
  1541. fpk_r:    rts
  1542.  
  1543.  
  1544. *+
  1545. * The first GEMDOS process can never terminate.
  1546. * This is not a good feature.
  1547. * Kludge around it -- re-initialize the stack
  1548. * and return to the guy who called us to begin with.
  1549. *
  1550. *-
  1551. au_dn:    move.l    origstk,sp        ; restore original stack
  1552.     move.l    autoret,-(sp)        ; get return addr
  1553.     rts                ; just jump there ...
  1554.  
  1555.  
  1556. *--- "bss" for auto-exec:
  1557. autoret:    dc.l    0        ; -> _auto's caller (yeccch)
  1558. pathname:    dc.l    0        ; -> filespec's pathname
  1559. filename:    dc.l    0        ; -> filename part of path
  1560. origstk:    dc.l    0        ; =  original supervisor stack
  1561. autodma:    dcb.b    44,0        ; 44 bytes for directory search
  1562. autoname:    dcb.b    32,0        ; 32 bytes for path+filename
  1563.     even
  1564.  
  1565.  
  1566. *    move.b    #$100-$20,d7    ; return to TOS ROMs
  1567. *    rts
  1568.  
  1569. msg_loaded:
  1570.     dc.b    'Atari ACSI/SCSI Driver'
  1571.   .if !SCDMA
  1572.     dc.b    ' (ND)'
  1573.   .endif ;SCDMA
  1574.     dc.b    13,10
  1575.     dc.b    '  ('
  1576.     VERSION
  1577.     dc.b    ')',13,10
  1578.     dc.b    0
  1579.     even
  1580.  
  1581. *
  1582. *  Terminate and stay resident;
  1583. *  installed driver under GEMDOS.
  1584. *
  1585. nboot2:    
  1586.     move.l    d0,-(sp)    ; save D0
  1587.     pea    msg_loaded(pc)    ; print announcement
  1588.     move.w    #9,-(sp)
  1589.     trap    #1
  1590.     addq    #6,sp
  1591.     move.l    (sp)+,d0
  1592.  
  1593.     move.w    #0,-(sp)    ; exit code
  1594.     move.l    d0,-(sp)
  1595.     move.w    #$31,-(sp)    ; terminate and stay resident
  1596.     trap    #1        ; should never come back...
  1597.     illegal
  1598.  
  1599.  
  1600. * page 
  1601.  .if ospool
  1602. *+
  1603. *  Wire more pool into various ROM releases.
  1604. *
  1605. *    Passed:    nothing
  1606. *    Returns:    D0 = #bytes extra used
  1607. *
  1608. *-
  1609. pool_install:
  1610.     move.l    _sysbase,a3        ; a3 -> base of OS
  1611.  
  1612. * make sure we're in ROM,
  1613. * then get address of RAM location to patch:
  1614.  
  1615.     cmp.l    #$800000,a3        ; better be ROM
  1616.     blt    notrom
  1617.     lea    pool_tab(pc),a0        ; a0 -> table to match
  1618. pi_lp:    move.l    (a0)+,d1        ; d1 = date to match
  1619.     beq    badrom            ; (forget it, end of list)
  1620.     move.l    (a0)+,a2        ; a2 -> _root address for that date
  1621.     cmp.l    $18(a3),d1        ; match dates?
  1622.     bne    pi_lp            ; (no -- try again)
  1623.  
  1624.     lea    poolbuf+2,a0        ; a0 -> base of first buffer
  1625.     move.w    #numchunks-1,d0        ; d0 = count-1
  1626. pin_1:    lea    chunksiz(a0),a1        ; a1 -> next buffer
  1627.     move.l    a1,(a0)            ; buffer -> next one
  1628.     move.w    #chunkno,-2(a0)        ; install chunksiz
  1629.     move.l    a1,a0            ; a0 -> next buffer
  1630.     dbra    d0,pin_1        ; (do some more)
  1631.  
  1632.     sub.w    #chunksiz,a0        ; a0 -> last block
  1633.     move.l    chunkno*4(a2),(a0)    ; last block -> first in root
  1634.     move.l    #poolbuf+2,chunkno*4(a2) ; root -> first of ours
  1635.     move.l    #numchunks*chunksiz,d0    ; d0 = amount of BSS used **AKP**
  1636.     rts                ; return OK
  1637.  
  1638. *+
  1639. *  Print warning messages
  1640. *  about bogus versions of the
  1641. *  operating system.  Assume that
  1642. *  every OS past 1-May-1986 has the
  1643. *  pool fix installed.
  1644. *
  1645. *-
  1646. ok_date    =    %0000110010100001    ; 1-May-1986
  1647. notrom:    lea    m_notrom(pc),a0        ; ram-based system (5/29!)
  1648.     bra.s    bdrom1
  1649. badrom:    lea    m_badrom(pc),a0        ; illegal ROM system
  1650. bdrom1:    cmp.w    #ok_date,$1e(a3)    ; if ok_date <= os_dosdate(a3) 
  1651.     bcc    bdrom2            ; then don't print anything
  1652.  
  1653.     move.l    a0,-(sp)        ; print nasty message
  1654.     move.w    #9,-(sp)
  1655.     trap    #1
  1656.     addq    #6,sp
  1657.  
  1658. * print msg and wait for RETURN
  1659.     pea    keymsg(pc)
  1660.     move.w    #9,-(sp)
  1661.     trap    #1
  1662.     addq    #6,sp
  1663.  
  1664. bdrom3:    move.w    #2,-(sp)        ; wait for [RETURN]
  1665.     move.w    #2,-(sp)
  1666.     trap    #13
  1667.     addq    #4,sp
  1668.     cmp.w    #13,d0
  1669.     bne    bdrom3
  1670.  
  1671. bdrom2:    moveq    #0,d0            ; 0 extra bytes used
  1672.     rts
  1673.  
  1674. keymsg:    dc.b    'Hard disk driver not loaded; hit RETURN',13,10
  1675.     dc.b    'key to continue:',13,10
  1676.     dc.b    0
  1677.  
  1678. m_notrom:
  1679.     dc.b    '*** WARNING ***',13,10,7
  1680.     dc.b    'This hard disk driver may not work with',13,10,7
  1681.     dc.b    'a disk-based version of TOS; files on',13,10,7
  1682.     dc.b    'your hard disk may be damaged.',13,10,7
  1683.     dc.b    13,10,7
  1684.     dc.b    0
  1685.  
  1686. m_badrom:
  1687.     dc.b    '*** WARNING ***',13,10,7
  1688.     dc.b    'You are using an unofficial ROM release',13,10,7
  1689.     dc.b    'of the operating system.  This driver',13,10,7
  1690.     dc.b    'may not work correctly with it.  Files',13,10,7
  1691.     dc.b    'on your hard disk may be damaged.',13,10,7
  1692.     dc.b    13,10,7
  1693.     dc.b    0
  1694.     even
  1695.  
  1696.  
  1697. *+
  1698. *  Table of ROM release dates / _root addresses
  1699. *  update these for new ROM releases that need the patch.
  1700. *
  1701. *-
  1702. pool_tab:
  1703.     dc.l    $11201985,$56fa        ; USA and UK, 20-Nov-1985
  1704.     dc.l    $02061986,$56fa        ; Germany, 6-Feb-1986
  1705.     dc.l    $04241986,$56fa        ; France, 24-Apr-1986
  1706.     dc.l    0
  1707.  .endif
  1708.  
  1709. * page 
  1710.  
  1711. BPBLEN    equ    18
  1712.     .globl    _puns
  1713. _puns:
  1714. puns:    dc.w    0
  1715.  
  1716.     .globl    _pun
  1717. _pun:
  1718. pun:    dcb.b    maxunits,0
  1719.     .globl    _partstart
  1720. _partstart:
  1721. start:    dcb.l    maxunits,0
  1722. bpbs:    dcb.b    maxunits*18,0
  1723.  
  1724. lastrwtm:    dc.l    0        ; ``_hz_200 + 1'' at last _do_rw()
  1725. tocount:    dc.l    1        ; timeout counter
  1726. retrycnt:    dc.w    1        ; retry counter
  1727.     .globl    _retries
  1728. _retries:    dc.w    nretries    ; number of retries to do
  1729.  
  1730. o_init:        dc.l    1
  1731. o_bpb:        dc.l    1
  1732. o_rw:        dc.l    1
  1733. o_mediach:    dc.l    1
  1734.  
  1735.  .if ospool
  1736. poolbuf:    dc.w    0
  1737.  .endif
  1738.  
  1739. * page 
  1740. * ---------------- Installer ----------------
  1741. i_sasi1: nop
  1742.  
  1743.     tst.w    bootloaded        ; if boot-loaded, don't Super()
  1744.     bne    nboot3
  1745.     clr.l    -(sp)            ; it's a bird...
  1746.     move.w    #$20,-(sp)        ;    ... it's a plane ...
  1747.     trap    #1            ;      ... no, its:
  1748.     addq    #6,sp            ; SOOUPERUSER!
  1749.     move.l    d0,savssp        ; "Faster than a prefetched opcode..."
  1750.  
  1751. nboot3:    move    #maxunits-1,d1
  1752.     moveq    #-1,d0            ; a bad pun
  1753.     lea    pun,a0
  1754. i_sasi2: move.b    d0,(a0)+
  1755.     dbra    d1,i_sasi2
  1756.  
  1757.   .if VERBOSE
  1758.     andi.b    #($FF-$1E),IERA    ; turn off MFP serial interrupts
  1759.     andi.b    #($FF-$1E),IMRA    ; turn off MFP serial interrupts
  1760.  
  1761.     bsr    crlf
  1762.     move.l    #msg_loaded,-(sp)
  1763.     bsr    puts
  1764.     addq    #4,sp
  1765.   .endif ;VERBOSE
  1766.  
  1767.   .if SCSI
  1768.     bsr    resetSCSI    ; reset the SCSI bus
  1769.   .endif ;SCSI
  1770.  
  1771.     move    #2,clun            ; current logical unit number
  1772.     move.l    #4,cdbit        ; current drive bit
  1773.     move    #0,cpun            ; current physical unit number
  1774.     move    #0,installed        ; none installed yet
  1775.     move    #0,puns            ; no physical units found
  1776.  
  1777. i_sasi3:
  1778.     move.w    cpun,-(sp)        ; pread(sectno, cnt, buf, physunit)
  1779.     move.l    #pbuf,-(sp)
  1780.     move.w    #1,-(sp)        ; 1 sector
  1781.     move.l    #0,-(sp)        ; sectno = 0
  1782.     bsr    pread            ; try to read root sector
  1783.     adda    #12,sp
  1784.  
  1785.     tst.w    d0
  1786.     bne    i_sasi4            ; no controller/disk of that ACSI unit
  1787.  
  1788.     addq    #1,puns            ; found a physical unit
  1789.  
  1790.     bsr    ppu
  1791.  
  1792.     addq    #1,cpun
  1793.     cmpi    #8,cpun
  1794.     bne    i_sasi3
  1795.  
  1796. i_sasi4:
  1797.   .if SCSI
  1798. ; hack in a SCSI partition
  1799.     move.w    #1,puns
  1800.     move.w    #1,installed
  1801.     move.b    #$40,pun+2
  1802.     move.l    #2,start+(2*4)
  1803.     ori.l    #4,_drvbits
  1804.  
  1805.     movea.l    #bpbs+(2*BPBLEN),a2
  1806.     lea    thebpb,a1
  1807.     move    #BPBLEN-1,d0
  1808. .4:    move.b    (a1)+,(a2)+
  1809.     dbra    d0,.4
  1810.  
  1811.   .endif ;SCSI
  1812.     tst    puns            ; any drives found?
  1813.     beq    isase            ; nope, so just terminate
  1814.  
  1815.     clr.l    a5            ; zeropage ptr
  1816.     move.l    hdv_bpb(a5),o_bpb    ; save old vectors
  1817.     move.l    hdv_rw(a5),o_rw
  1818.     move.l    hdv_mediach(a5),o_mediach
  1819.  
  1820.     move.l    #hbpb,hdv_bpb(a5)    ; install our new ones
  1821.     move.l    #hrw,hdv_rw(a5)
  1822.     move.l    #hmediach,hdv_mediach(a5)
  1823.     move.l    #_puns,pun_ptr(a5)
  1824.  
  1825.     bra    isasi5        ; must get back into resident part
  1826.  
  1827. isase:    tst.w    bootloaded    ; if bootloaded, free block and punt
  1828.     bne    isaseb
  1829.     move.l    savssp,-(sp)    ; become a mild mannered user process
  1830.     move.w    #$20,-(sp)    ; Super(savssp)
  1831.     trap    #1
  1832.     addq    #6,sp
  1833.  
  1834.     move.w    #-1,-(sp)    ; exit code
  1835.     move.w    #$4C,-(sp)    ; terminate
  1836.     trap    #1        ; should never come back...
  1837.     illegal
  1838.  
  1839. *
  1840. *  Couldn't install driver, return to boot code
  1841. *
  1842. isaseb:    move.l    baseaddr,-(sp)    ; Mfree(baseaddr)
  1843.     move.w    #$49,-(sp)
  1844.     trap    #1
  1845.     addq.l    #6,sp
  1846.     move.b    #$100-$20,d7    ; return to TOS ROMs
  1847.     rts
  1848.  
  1849.  
  1850. * page 
  1851. *+
  1852. * pread(sectno, cnt, buf, physunit)
  1853. * LONG sectno;
  1854. * BYTE *buf; (word aligned)
  1855. * WORD cnt,physunit;
  1856. *
  1857. * Passed:    dev.w        $a(a0)    $e(sp)
  1858. *        &buf.l        $6(a0)    $a(sp)
  1859. *        cnt.w        $4(a0)    $8(sp)
  1860. *        sectno.l    $0(a0)    $4(sp)
  1861. *
  1862. * Returns:    -1 if we could not read it
  1863. *            (may not exist)
  1864. *-
  1865.     .globl    _pread
  1866. _pread:
  1867. pread:    move    _retries,retrycnt
  1868. pread1:    lea    4(sp),a0        ; frame pointer
  1869.     move.w    $a(a0),-(sp)        ; push physical unit number
  1870.     move.l    $6(a0),-(sp)        ; buffer address
  1871.     move.w    $4(a0),-(sp)        ; number to read
  1872.     move.l    (a0),-(sp)        ; sector number
  1873.     bsr    _hread
  1874.     adda    #12,sp
  1875.     tst    d0
  1876.     beq    pread9            ; no problems
  1877.     bmi    pread8            ; timeout, does not exist
  1878.     subq    #1,retrycnt        ; read error, try try again
  1879.     bpl    pread1
  1880. pread8:    moveq    #-1,d0
  1881.     rts
  1882.  
  1883. pread9:    move    #$8000,d0        ; delay for completion byte
  1884. preada:    subq    #1,d0
  1885.     bne    preada
  1886.     clr.l    d0            ; flag no errors
  1887.     rts
  1888.  
  1889. * page 
  1890. *+
  1891. * ppu
  1892. * Partition physical unit
  1893. *
  1894. *-
  1895. ppu:    move    #0,npart        ; number of partitions we have found
  1896.     movea.l    #pbuf+hd_siz,a0
  1897.     tst.l    (a0)+
  1898.     beq    ppu3            ; if 0, must not be valid
  1899.  
  1900.     moveq    #4-1,d1            ; maximum number of partitions/unit
  1901. ppu1:    movem.l    d1/a0,-(sp)
  1902.     tst.b    (a0)+            ; check the valid partition flag
  1903.     beq    ppu2            ; if 0, not a valid parition
  1904.  
  1905.     addq    #1,npart        ; number of partitions this unit
  1906.  
  1907.     cmpi.b    #'G',(a0)+        ; must find GEM as type
  1908.     bne    ppu2
  1909.     cmpi.b    #'E',(a0)+
  1910.     bne    ppu2
  1911.     cmpi.b    #'M',(a0)+
  1912.     bne    ppu2
  1913.  
  1914.     tst.l    4(a0)            ; is the size 0?
  1915.     beq    ppu2            ; then not a valid partition
  1916.  
  1917.     move.l    (a0),-(sp)        ; save start sector
  1918.  
  1919.     bsr    nxtdrv
  1920.  
  1921.     move.l    (sp)+,d1        ; recall start sector
  1922.  
  1923.     tst    d0            ; valid unit?
  1924.     bmi    ppu2
  1925.  
  1926.     movem.l    d1/a0-a1,-(sp)
  1927.  
  1928.     move.l    d1,-(sp)        ; getbpb(partition_start)
  1929.     bsr    getbpb            ; build bpb and put it in place
  1930.     addq    #4,sp
  1931.  
  1932.     movem.l    (sp)+,d1/a0-a1
  1933.  
  1934.     tst    d0
  1935.     bne    ppu2
  1936.  
  1937.     move.w    cpun,d0
  1938.     move.b    d0,(a0)
  1939.  
  1940.     move.l    d1,(a1)            ; start of partition
  1941.  
  1942.     addq    #1,clun
  1943.     addq    #1,installed        ; actually installed a hard disk
  1944.  
  1945. ppu2:    movem.l    (sp)+,d1/a0
  1946.     adda    #12,a0
  1947.     dbra    d1,ppu1
  1948.  
  1949.     tst    npart            ; did we find any?
  1950.     bne    ppu9
  1951.  
  1952. ppu3:    bsr    nxtdrv            ; no valid partitions found, assume
  1953.     move    cpun,d0            ;  whole thing is one big GEM disk
  1954.     move.b    d0,(a0)
  1955.     move.w    #0,(a1)            ; starts at 0
  1956.     lea    thebpb,a1
  1957.     move    #BPBLEN-1,d0
  1958. ppu4:    move.b    (a1)+,(a2)+
  1959.     dbra    d0,ppu4
  1960.  
  1961.     addq    #1,clun
  1962.     addq    #1,installed
  1963.  
  1964. ppu9:    rts
  1965.  
  1966. * page 
  1967. *+
  1968. * nxtdrv    (of clun, cdbit)
  1969. *    returns d0 = clun, or negative if error
  1970. *        a0 -> pun(clun)
  1971. *        a1 -> start(clun)
  1972. *        a2 -> bpbs(clun)
  1973. *-
  1974.  
  1975. nxtdrv:    cmpi    #maxunits,clun        ; have we already hit maximum?
  1976.     bge    nxtd9            ; yes, so signal error
  1977.  
  1978.     move.l    cdbit,d1        ; get the next bit to turn on
  1979.     move.l    _drvbits,d0        ; tell TOS we have the drive
  1980.     or.l    d1,d0
  1981.     move.l    d0,_drvbits
  1982.  
  1983.     asl.l    #1,d1
  1984.     move.l    d1,cdbit
  1985.     move    clun,d0
  1986.     lea    pun,a0
  1987.     adda    d0,a0
  1988.     lea    start,a1
  1989.     move    d0,d1
  1990.     asl    #2,d1            ; *4 for index into table of longs
  1991.     adda    d1,a1
  1992.     lea    bpbs,a2
  1993.     move    d0,d1
  1994.     mulu    #BPBLEN,d1
  1995.     adda    d1,a2
  1996.     rts
  1997.  
  1998. nxtd9:    moveq    #-1,d0
  1999.     rts
  2000.  
  2001. * page 
  2002. *+
  2003. * getbpb(sectorno)
  2004. * LONG sectorno;
  2005. *-
  2006.  
  2007. getbpb:    move.l    a2,-(sp)
  2008.  
  2009.     move.w    cpun,-(sp)        ; try to read this partition's
  2010.     move.l    #lbuf,-(sp)        ; boot sector
  2011.     move.w    #1,-(sp)        ; number of sectors
  2012.     move.l    16(sp),-(sp)        ; sectorno
  2013.     bsr    pread            ; pread(sectno, cnt, buf, physunit)
  2014.     adda    #12,sp
  2015.  
  2016.     movea.l    (sp)+,a2
  2017.  
  2018.     tst    d0            ; any trouble reading?
  2019.     bmi    getb9            ; bummer
  2020.  
  2021.     lea    lbuf,a3            ; pointer to boot sector
  2022.  
  2023.     move    #$0b,d0
  2024.     bsr    getlhw
  2025.     move    d0,(a2)+        ; =byt/sec
  2026.     move    d0,d1
  2027.  
  2028.     clr.w    d0
  2029.     move.b    $d(a3),d0
  2030.     move    d0,(a2)+        ; =sec/cluster
  2031.  
  2032.     mulu    d1,d0
  2033.     move    d0,(a2)+        ; =byt/cluster
  2034.  
  2035.     move    #$11,d0
  2036.     bsr    getlhw            ; number of directory entries
  2037.     mulu    #32,d0            ; size of each entry
  2038.     divu    d1,d0            ; number of sectors required
  2039.     move.l    d0,d1
  2040.     swap    d1
  2041.     tst    d1
  2042.     beq    getb1
  2043.     addq    #1,d0            ; round up
  2044. getb1:    move    d0,(a2)+        ; =rdlen
  2045.     move    d0,d2
  2046.  
  2047.     move    #$16,d0
  2048.     bsr    getlhw
  2049.     move    d0,(a2)+        ; =FATsize
  2050.     move    d0,d1
  2051.  
  2052.     move    #$e,d0
  2053.     bsr    getlhw            ; number of reserved sectors
  2054.     add    d1,d0
  2055.     move    d0,(a2)+        ; =2nd FAT start
  2056.  
  2057.     add    d1,d0            ; plus size of second fat
  2058.     add    d2,d0            ; plus rdlen
  2059.     move    d0,(a2)+        ; = data start
  2060.     move    d0,d2            ; save start of data
  2061.  
  2062.     move    #$13,d0
  2063.     bsr    getlhw            ; number of sectors on media
  2064.     sub    d2,d0            ; subtract number used by FATs,dir,boot
  2065.     clr.l    d1
  2066.     move    d0,d1
  2067.     clr    d0
  2068.     move.b    $d(a3),d0        ; number of sectors/cluster
  2069.     divu    d0,d1            ; rounding down
  2070.     move    d1,(a2)+        ; =number of clusters
  2071.     move    #1,(a2)            ; =flags, 16 bit fats
  2072.     clr.l    d0            ; no errors
  2073. getb9:    rts
  2074.  
  2075. *+
  2076. * WORD getlhw(d0=offset)
  2077. * returns word (low,high) from 0(D0,A3)
  2078. *-
  2079.  
  2080. getlhw:    move    d1,-(sp)        ; preserve d1
  2081.     move.b    1(a3,d0.w),d1
  2082.     lsl.w    #8,d1
  2083.     move.b    0(a3,d0.w),d1
  2084.     move    d1,d0
  2085.     move    (sp)+,d1
  2086.     rts
  2087.  
  2088. * page 
  2089.   .if    format
  2090. *+
  2091. *  _doformat - format hard disk
  2092. *
  2093. *    Synopsis:    LONG _doformat(dev, interlv)
  2094. *        WORD dev;            4(sp).W
  2095. *        WORD interlv;            6(sp).W
  2096. *
  2097. *-
  2098. acfmt:    dc.b    4    ; format command + devno (upper 3 bits)
  2099.     dc.b    0    ; (unused)
  2100.     dc.b    0    ; (unused) data pattern
  2101. ac_in:    dc.b    0,0    ; interleave factor MSB, LSB
  2102.     dc.b    0    ; reserved
  2103.     even
  2104.  
  2105.     .globl    _doformat
  2106. _doformat:
  2107.     move.w    4(sp),d0        ; set dev#
  2108.     lsl.b    #5,d0            ; up 5 bits, fill in 0s
  2109.     or.b    #4,d0            ; OR-in with FORMAT command
  2110.     move.b    d0,acfmt        ; stuff into command frame
  2111.     move.b    6(sp),ac_in        ; set interleave
  2112.     move.b    7(sp),ac_in+1
  2113.  
  2114.     lea    acfmt(pc),a0        ; pick up pointer to the command block
  2115.     clr.w    d0
  2116.     st    flock            ; lock FIFO
  2117.     move.w    #$88,wdl
  2118.     move.b    (a0)+,d0        ; get the command byte
  2119.     swap    d0
  2120.     move.w    #$8a,d0
  2121.     move.l    d0,wdc            ; byte wdc 8a wdl
  2122.  
  2123.     moveq    #(5-1),d1        ; write remaining 5 bytes of command
  2124. fmt1:    bsr    _qdone
  2125.     bmi    _hto
  2126.     move.b    (a0)+,d0        ; next byte of command
  2127.     swap    d0
  2128.     move.w    #$8a,d0
  2129.     move.l    d0,wdcwdl
  2130.     dbra    d1,fmt1
  2131.  
  2132. fmt2:    btst    #5,gpip            ; wait (forever) for completion
  2133.     bne    fmt2
  2134.     move.w    wdc,d0            ; get the status
  2135.     andi.w    #$00FF,d0        ; only low byte is significant
  2136.     bra    _hdone            ; cleanup after IRQ
  2137.  
  2138. * page 
  2139. *+
  2140. *  _mode_set - set hard disk format parameters
  2141. *
  2142. *    Synopsis:    LONG _mode_set(dev, parms)
  2143. *        WORD dev;            4(sp).W
  2144. *        char *parms;            6(sp).L
  2145. *
  2146. *-
  2147.     .globl    _mode_set
  2148. _mode_set:
  2149.     st    flock            ; lock FIFO
  2150.     move.l    6(sp),-(sp)        ; -> parameter block address
  2151.     bsr    _setdma            ; set DMA there
  2152.     addq    #4,sp
  2153.  
  2154. * write command and dev#
  2155.     move.w    #$88,wdl
  2156.     move.w    4(sp),d0        ; d0 = (dev << 5) << 16
  2157.     lsl.b    #5,d0
  2158.     swap    d0            ; in upper word
  2159.     or.l    #$0015008a,d0        ; write dev# + ModeSelect + FIFO bits
  2160.     move.l    d0,wdcwdl        ; mdsel+dev wdc 8a wdl (byte 0)
  2161.     bsr    _qdone
  2162.     bmi    wdx
  2163.  
  2164.     move.l    #$0000008a,wdcwdl    ; byte 1
  2165.     bsr    _qdone
  2166.     bmi    wdx
  2167.  
  2168.     move.l    #$0000008a,wdcwdl    ; byte 2
  2169.     bsr    _qdone
  2170.     bmi    wdx
  2171.  
  2172.     move.l    #$0000008a,wdcwdl    ; byte 3
  2173.     bsr    _qdone
  2174.     bmi    wdx
  2175.  
  2176.     move.l    #$0016008a,wdcwdl    ; 22 bytes of parameters (byte 4)
  2177.     bsr    _qdone
  2178.     bmi    wdx
  2179.  
  2180.     move.w    #$90,wdl        ; reset the DMA chip
  2181.     nop
  2182.     move.w    #$190,wdl
  2183.     nop
  2184.     move.w    #$01,wdc        ; 1 sector of DMA (actually less)
  2185.     nop
  2186.     move.w    #$18a,wdl
  2187.     nop
  2188.     move.l    #$00000100,wdcwdl    ; byte 5 (control byte)
  2189.     move.w    #$18a,d0        ; wdl value
  2190.     bsr    _endcmd            ; wait for command completion
  2191. wdx:    bra    _hdone
  2192.  
  2193.   .endif  ; format
  2194.  
  2195. * page 
  2196.   
  2197.   .if    mdsense
  2198. *+
  2199. *  _md_sense - get hard disk format parameters
  2200. *
  2201. *    Synopsis:    LONG _md_sense(dev, parms)
  2202. *        WORD dev;            4(sp).W
  2203. *        char *parms;            6(sp).L
  2204. *
  2205. *-
  2206.     .globl    _md_sense
  2207. _md_sense:
  2208.     st    flock            ; lock FIFO
  2209.     move.l    6(sp),-(sp)        ; -> parameter block address
  2210.     bsr    _setdma            ; set DMA there
  2211.     addq    #4,sp
  2212.  
  2213. * write command and dev#
  2214.     move.w    #$88,wdl
  2215.     move.w    4(sp),d0        ; d0 = (dev << 5) << 16
  2216.     lsl.b    #5,d0
  2217.     swap    d0            ; in upper word
  2218.     or.l    #$001a008a,d0        ; write dev# + ModeSense + FIFO bits
  2219.     move.l    d0,wdcwdl        ; mdsel+dev wdc 8a wdl (byte 0)
  2220.     bsr    _qdone
  2221.     bmi    wdx1
  2222.  
  2223.     move.l    #$0000008a,wdcwdl    ; byte 1
  2224.     bsr    _qdone
  2225.     bmi    wdx1
  2226.  
  2227.     move.l    #$0000008a,wdcwdl    ; byte 2
  2228.     bsr    _qdone
  2229.     bmi    wdx1
  2230.  
  2231.     move.l    #$0000008a,wdcwdl    ; byte 3
  2232.     bsr    _qdone
  2233.     bmi    wdx1
  2234.  
  2235.     move.l    #$0016008a,wdcwdl    ; 22 bytes of parameters (byte 4)
  2236.     bsr    _qdone
  2237.     bmi    wdx1
  2238.  
  2239.     move.w    #$190,wdl        ; reset the DMA chip
  2240.     nop
  2241.     move.w    #$90,wdl
  2242.     nop
  2243.     move.w    #$01,wdc        ; 1 sector of DMA (actually less)
  2244.     nop
  2245.     move.w    #$8a,wdl
  2246.     nop
  2247.     move.l    #0,wdcwdl        ; byte 5 (control byte)
  2248.     move.w    #$8a,d0            ; wdl value
  2249.     bsr    _endcmd            ; wait for command completion
  2250. wdx1:    bra    _hdone
  2251.  
  2252.   .endif  ; mdsense
  2253.  
  2254. * page 
  2255.   .if    sahdxc
  2256. *+
  2257. * LONG _dosahdxc( dev, addr ) BYTE *addr;
  2258. *    do a simple (no DMA) ahdx command
  2259. *-
  2260.     .globl    _dosahdxc
  2261. _dosahdxc: movea.l 6(sp),a0        ; pick up pointer to the command block
  2262.     clr.w    d0
  2263.     st    flock            ; lock FIFO
  2264.     move.w    #$88,wdl
  2265.     move    4(sp),d0        ; get the unit number
  2266.     lsl    #5,d0            ; shift it into place
  2267.     or.b    (a0)+,d0        ; or in the command byte
  2268.     swap    d0
  2269.     move.w    #$8a,d0
  2270.     move.l    d0,wdcwdl        ; send it to the controller
  2271.  
  2272.     moveq    #(5-1),d1        ; write remaining 5 bytes of command
  2273. dosac1:    bsr    _qdone
  2274.     bmi    _hto
  2275.     move.b    (a0)+,d0        ; next byte of command
  2276.     swap    d0
  2277.     move.w    #$8a,d0
  2278.     move.l    d0,wdcwdl
  2279.     dbra    d1,dosac1
  2280.  
  2281.     bsr    _fdone            ; wait for the command to complete
  2282.     bmi    _hto
  2283.  
  2284.     move.w    wdc,d0            ; get the status
  2285.     andi.w    #$00FF,d0        ; only low byte is significant
  2286.  
  2287.     bra    _hdone            ; cleanup after IRQ
  2288.  
  2289.   .endif    ; sahdxc
  2290.  
  2291. * page 
  2292.   .if s10mb
  2293. *+
  2294. * BPB for 10MB drive
  2295. *-
  2296. thebpb:    dc.w    512            ; #bytes/sector
  2297.     dc.w    2            ; #sectors/cluster
  2298.     dc.w    1024            ; #bytes/cluster
  2299.     dc.w    16            ; rdlen (256 root files) (in sectors)
  2300.     dc.w    41            ; FATsiz (10300 FAT entries) (sectors)
  2301.     dc.w    42            ; 2nd FAT start
  2302.     dc.w    99            ; data start (in sectors)
  2303.     dc.w    10300            ; #clusters (approximate here)
  2304.     dc.w    1            ; flags (16-bit FATs)
  2305.   .endif
  2306.  
  2307.   .if s11mb
  2308. *+
  2309. * BPB for 11MB Syquest partition
  2310. *-
  2311. thebpb:    dc.w    512            ; #bytes/sector
  2312.     dc.w    2            ; #sectors/cluster
  2313.     dc.w    1024            ; #bytes/cluster
  2314.     dc.w    17            ; rdlen (512 root files) (in sectors)
  2315.     dc.w    43            ; FATsiz (20736 FAT entries) (sectors)
  2316.     dc.w    44            ; 2nd FAT start
  2317.     dc.w    104            ; data start (in sectors)
  2318.     dc.w    10837            ; #clusters (approximate here)
  2319.     dc.w    1            ; flags (16-bit FATs)
  2320.   .endif
  2321.  
  2322.   .if s20mb
  2323. *+
  2324. * BPB for 20MB drive
  2325. *-
  2326. thebpb:    dc.w    512            ; #bytes/sector
  2327.     dc.w    2            ; #sectors/cluster
  2328.     dc.w    1024            ; #bytes/cluster
  2329.     dc.w    32            ; rdlen (512 root files) (in sectors)
  2330.     dc.w    81            ; FATsiz (20736 FAT entries) (sectors)
  2331.     dc.w    82            ; 2nd FAT start
  2332.     dc.w    195            ; data start (in sectors)
  2333.     dc.w    20710            ; #clusters (approximate here)
  2334.     dc.w    1            ; flags (16-bit FATs)
  2335.   .endif
  2336.  
  2337.   .if sahdxc
  2338.  
  2339. actur:    dc.b    0,0,0,0,0,0        ; atari command: test unit ready
  2340.  
  2341.   .endif ;sahdxc
  2342.  
  2343.  
  2344.     .even
  2345.  
  2346.     bss
  2347. savssp:    ds.l    1            ; (saved SSP)
  2348. clun:    ds.w    1
  2349. cpun:    ds.w    1
  2350. cdbit:    ds.l    1
  2351. npart:    ds.w    1            ; number of partitions found this pun
  2352. installed: ds.w    1            ; number hard disk partitions installed
  2353.  
  2354. hd_siz    equ    $1c2            ; offset into pbuf for partition info
  2355. pbuf:    ds.b    512
  2356. lbuf:    ds.b    512
  2357.  
  2358.     end
  2359.  -> filename part of path
  2360. origstk:    dc.l    0        ; =  original supervisor stack
  2361. autodma:    dcb.b    44,0        ; 44
  2362.